MATCH function

*Applies To: Excel 2016 Excel 2013 Excel 2010 Excel 2007 Excel 2016 for Mac**More...*

The **MATCH** function searches for a specified item in a range of cells, and then returns the relative position of that item in the range. For example, if the range A1:A3 contains the values 5, 25, and 38, then the formula **=MATCH(25,A1:A3,0)** returns the number 2, because 25 is the second item in the range.

**TIP:** Use **MATCH** instead of one of the **LOOKUP** functions when you need the position of an item in a range instead of the item itself. For example, you might use the **MATCH** function to provide a value for the ***row\_num*** argument of the **INDEX** function.

Syntax

MATCH(lookup\_value, lookup\_array, [match\_type])

The MATCH function syntax has the following arguments:

* **lookup\_value**    Required. The value that you want to match in ***lookup\_array***. For example, when you look up someone's number in a telephone book, you are using the person's name as the lookup value, but the telephone number is the value you want.

The ***lookup\_value*** argument can be a value (number, text, or logical value) or a cell reference to a number, text, or logical value.
* **lookup\_array**    Required. The range of cells being searched.
* **match\_type**    Optional. The number -1, 0, or 1. The ***match\_type*** argument specifies how Excel matches ***lookup\_value*** with values in ***lookup\_array***. The default value for this argument is 1.

The following table describes how the function finds values based on the setting of the ***match\_type***argument.

| **Match\_type** | **Behavior** |
| --- | --- |
| 1 or omitted | **MATCH** finds the largest value that is less than or equal to ***lookup\_value***. The values in the ***lookup\_array*** argument must be placed in ascending order, for example: ...-2, -1, 0, 1, 2, ..., A-Z, FALSE, TRUE. |
| 0 | **MATCH** finds the first value that is exactly equal to ***lookup\_value***. The values in the ***lookup\_array*** argument can be in any order. |
| -1 | **MATCH** finds the smallest value that is greater than or equal to***lookup\_value*. The values in the *lookup\_array* argument must be placed in descending order, for example: TRUE, FALSE, Z-A, ...2, 1, 0, -1, -2, ..., and so on.** |

* **MATCH** returns the position of the matched value within ***lookup\_array***, not the value itself. For example, **MATCH("b",{"a","b","c"},0)** returns 2, which is the relative position of "b" within the array {"a","b","c"}.
* **MATCH** does not distinguish between uppercase and lowercase letters when matching text values.
* If **MATCH** is unsuccessful in finding a match, it returns the #N/A error value.
* If ***match\_type*** is 0 and ***lookup\_value*** is a text string, you can use the wildcard characters — the question mark (**?**) and asterisk (**\***) — in the ***lookup\_value*** argument. A question mark matches any single character; an asterisk matches any sequence of characters. If you want to find an actual question mark or asterisk, type a tilde (**~**) before the character.

Example

Copy the example data in the following table, and paste it in cell A1 of a new Excel worksheet. For formulas to show results, select them, press F2, and then press Enter. If you need to, you can adjust the column widths to see all the data.

| **Product** | **Count** |  |
| --- | --- | --- |
| Bananas | 25 |  |
| Oranges | 38 |  |
| Apples | 40 |  |
| Pears | 41 |  |
| **Formula** | **Description** | **Result** |
| =MATCH(39,B2:B5,1) | Because there is not an exact match, the position of the next lowest value (38) in the range B2:B5 is returned. | 2 |
| =MATCH(41,B2:B5,0) | The position of the value 41 in the range B2:B5. | 4 |
| =MATCH(40,B2:B5,-1) | Returns an error because the values in the range B2:B5 are not in descending order. | #N/A |